deegree22_philosopher_fragments.xsl 6.34 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
		xmlns:app="http://www.deegree.org/app"
		xmlns:gco="http://www.isotc211.org/2005/gco"
		xmlns:gmd="http://www.isotc211.org/2005/gmd"
		xmlns:gml="http://www.opengis.net/gml"
		xmlns:wfs="http://www.opengis.net/wfs"
		xmlns:xlink="http://www.w3.org/1999/xlink"
		xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"		
		xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />

	<!-- 
			 This xslt should transform output from the WFS philosophers database
	     that you should install with deegree into fragments that can be linked 
			 into the template 'deegree fragments test template' by the WFS fragment 
			 harvester in GeoNetwork. 
	 -->

	<xsl:template match="wfs:FeatureCollection">
		<records>
			<xsl:if test="boolean( ./@timeStamp )">
				<xsl:attribute name="timeStamp">
					<xsl:value-of select="./@timeStamp"></xsl:value-of>
				</xsl:attribute>
			</xsl:if>
			<xsl:if test="boolean( ./@lockId )">
				<xsl:attribute name="lockId">
					<xsl:value-of select="./@lockId"></xsl:value-of>
				</xsl:attribute>
			</xsl:if>

			<xsl:apply-templates select="gml:featureMember"/>
		</records>
	</xsl:template>

	<xsl:template match="*[@xlink:href]" priority="20">
		<xsl:variable name="linkid" select="substring-after(@xlink:href,'#')"/>
		<xsl:apply-templates select="//*[@gml:id=$linkid]"/>
	</xsl:template>

	<xsl:template match="gml:featureMember">
		<xsl:apply-templates select="app:Philosopher"/>
	</xsl:template>

	<xsl:template match="app:Philosopher">
		<record>

			<!-- boundingBox -->

			<fragment id="boundingbox" uuid="{@gml:id}_boundingbox" title="{concat(app:name,':',app:id)}">
				<gmd:EX_Extent>
					<gmd:geographicElement>
						<gmd:EX_GeographicBoundingBox>
							<gmd:westBoundLongitude>
								<gco:Decimal><xsl:value-of select="substring-before(gml:boundedBy/gml:Envelope/gml:pos[1],' ')"/></gco:Decimal>
							</gmd:westBoundLongitude>
							<gmd:eastBoundLongitude>
								<gco:Decimal><xsl:value-of select="substring-after(gml:boundedBy/gml:Envelope/gml:pos[1],' ')"/></gco:Decimal>
							</gmd:eastBoundLongitude>
							<gmd:southBoundLatitude>
								<gco:Decimal><xsl:value-of select="substring-before(gml:boundedBy/gml:Envelope/gml:pos[2],' ')"/></gco:Decimal>
							</gmd:southBoundLatitude>
							<gmd:northBoundLatitude>
								<gco:Decimal><xsl:value-of select="substring-after(gml:boundedBy/gml:Envelope/gml:pos[2],' ')"/></gco:Decimal>
							</gmd:northBoundLatitude>
						</gmd:EX_GeographicBoundingBox>
					</gmd:geographicElement>
				</gmd:EX_Extent>	
			</fragment>

			<!-- pointOfContact -->

			<fragment id="contactinfo" uuid="{@gml:id}_contactinfo" title="{concat(app:name,':',app:id,':contactinfo')}">
				<gmd:CI_ResponsibleParty>
   				<gmd:individualName>
     				<gco:CharacterString>Dr Charlie Brown</gco:CharacterString>
   				</gmd:individualName>
   				<gmd:organisationName>
     				<gco:CharacterString>Silicon Graphics R4400 64bit Systems and Philosophy Management Section</gco:CharacterString>
   				</gmd:organisationName>
    			<gmd:positionName>
       			<gco:CharacterString>Part-time Chief Philosopher</gco:CharacterString>
    			</gmd:positionName>
    			<gmd:role>
       			<gmd:CI_RoleCode codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_RoleCode" codeListValue="pointOfContact"/>
    			</gmd:role> 	
				</gmd:CI_ResponsibleParty>
			</fragment>

			<!-- keywords -->

			<fragment id="keywords" uuid="{@gml:id}_keywords" title="{concat(app:name,':',app:id,':keywords')}">
				<gmd:descriptiveKeywords>
					<gmd:MD_Keywords>
						<xsl:for-each select="app:subject">
							<gmd:keyword>
								<gco:CharacterString><xsl:value-of select="."/></gco:CharacterString>
							</gmd:keyword>
						</xsl:for-each>
						<gmd:keyword>
							<gco:CharacterString>Philosophy</gco:CharacterString>
						</gmd:keyword>
						<gmd:type>
							<gmd:MD_KeywordTypeCode codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#MD_KeywordTypeCode" codeListValue="theme"/>
						</gmd:type>
					</gmd:MD_Keywords>
				</gmd:descriptiveKeywords>
			</fragment>

			<!-- citation -->

			<fragment id="citation" uuid="{@gml:id}_citation" title="{concat(app:name,':',app:id,':citation')}">
				<gmd:CI_Citation>
					<gmd:title>
						<gco:CharacterString>Information about the Philosopher <xsl:value-of select="app:name"/></gco:CharacterString>
					</gmd:title>
					<gmd:date>
						<gmd:CI_Date>
							<gmd:date>
								<gco:Date>
									<xsl:choose>
										<xsl:when test="boolean(//wfs:FeatureCollection/@timeStamp)">
											<xsl:value-of select="//wfs:FeatureCollection/@timeStamp"/>
										</xsl:when>
										<xsl:otherwise>
											<xsl:text>2009-05-24</xsl:text>
										</xsl:otherwise>
									</xsl:choose>
								</gco:Date>
							</gmd:date>
							<gmd:dateType>
								<gmd:CI_DateTypeCode codeList="http://www.isotc211.org/2005/resources/Codelist/gmxCodelists.xml#CI_DateTypeCode" codeListValue="publication"/>
							</gmd:dateType>
						</gmd:CI_Date>
					</gmd:date>
					<!-- xlink to contactinfo fragment defined above -->
					<gmd:citedResponsibleParty xlink:href="#{@gml:id}_contactinfo"/>
				</gmd:CI_Citation>
			</fragment>

			<!-- abstract -->

			<fragment id="abstract" uuid="{@gml:id}_abstract" title="{concat(app:name,':',app:id,':abstract')}">
				<gmd:abstract>
					<gco:CharacterString>
						Metadata about the Philosopher <xsl:value-of select="app:name"/>
						&#160;
						Sex: <xsl:value-of select="app:sex"/>
						&#160;
						<xsl:for-each select="app:isAuthorOf">
							Is the author of: <xsl:value-of select="app:Book/app:title"/>
							&#160;
						</xsl:for-each>
					</gco:CharacterString>
				</gmd:abstract>
			</fragment>

			<!-- temporal extent = lifespan -->

			<fragment id="tempextent" uuid="{@gml:id}_tempextent" title="{concat(app:name,':',app:id,':tempextent')}">
				<gmd:temporalElement>
					<gmd:EX_TemporalExtent>
						<gmd:extent>
							<gml:TimePeriod gml:id="">
								<gml:beginPosition><xsl:value-of select="app:dateOfBirth"/></gml:beginPosition>
								<gml:endPosition><xsl:value-of select="app:dateOfDeath"/></gml:endPosition>
							</gml:TimePeriod>
						</gmd:extent>
					</gmd:EX_TemporalExtent>
				</gmd:temporalElement>
			</fragment>

		</record>
	</xsl:template>


</xsl:stylesheet>